Gentlemen Language Spec (BNF Grammar)
by Michael Ardizzone and Tim Smith

NOTE: All non-terminals are enclosed in angle braces ("<" ">"). The lexer does permit extra spaces occasionally, but don't count on it. Spaces around operands are required.

<program>           ::= begin: <stmts> end.

<stmts>             ::= <stmt>; <stmts>
                    ::= <stmt>;

<stmt>              ::= <assign-stmt>
                    ::= <while-expr> 
                    ::= <if-expr>
                    ::= <print-stmt>
                    ::= <var-decl>

<var-decl>          ::= <type> <id>

<assign-stmt>       ::= <id> = <math-expr>

<print-stmt>        ::= print <id>
                    ::= print "<string>"

<while-expr>        ::= while (<bool-expr>) do <stmts> endwhile

<if-expr>           ::= if (<bool-expr>) then <stmts> endif

<bool-expr>         ::= <value> <bool-op> <value>

<value>             ::= <id> 
                    ::= "<string>"
                    ::= <number>

<math-expr>         ::= <value> <int-op> <math-expr>
                    ::= <value>

<bool-op>           ::= == 
                    ::= !=

<int-op>            ::= +

<type>              ::= int
                    ::= string

<id>                ::= <letter><id>
                    ::= <letter>

<number>            ::= <numeral><number>
                    ::= <numeral>

<string>            ::= <char><string>
                    ::= <char>

<letter>            ::= a | b | c | d | ... | x | y | z

<char>              ::= <letter>
                    ::= space

<numeral>           ::= 1 | 2 | 3 | ... | 8 | 9 | 0